【SAP ABAP】バッチインプットの概要とプログラム(CALL TRANSACTION)の作成方法を徹底解説！

2024年5月20日2025年3月7日

登場人物紹介

三崎レイナ
社会人1年目。新卒でITコンサルティングファームに就職。初配属がSAPプロジェクトにアサインされる。SAPがわからないことだらけで悩んでいたところ、会社の先輩にSAPラボの所長を紹介され、毎週末に所長とSAPのお勉強中！

博士
SAPラボの所長。SAP大好き博士！SAP導入プロジェクトを構想策定～運用保守まであらゆるフェーズを数多く経験。
いまは優しきおじいちゃんだが、プロマネバリバリの時代はかなり怖かったらしい。現在は引退しSAPの後進育成と啓蒙活動に従事中！
若者に負けぬようX（旧Twitter）も奮闘中。

この記事を読むメリット

SAPでのバッチインプットの概要が理解できるようになります。
バッチインプットレコーダーの使用方法が理解できるようになります。
ABAPを用いたバッチインプットプログラムの作成方法が理解できるようになります。

レイナ

バッチインプットを使ったプログラムを使えばトランザクションデータを作成できるって聞いたんだけど、どういったものなんだろう…？？

SAPではバッチインプットという機能を用い、SAP上で手作業で実施すべきことを自動化することが可能です。
例えばアドオンプログラムでバッチインプットを利用することで、マスタデータやトランザクションデータを登録することもできます。

今回はバッチインプットの概要からバッチインプットレコーダーの使用方法、ABAPを用いたバッチインプットプログラムの作成について解説します！

ABAPの全体像を知るならこちら

SAP ABAPまとめ

新着のSAPフリーランス案件

【FI】

【SAP FI/CO運用保守（チームリード）】フルリモート／計画管理・海外展開支援

: ～1,250,000円 / 月

: フルリモート

: 運用・保守

稼働率：: 100%

作業内容：

SAPシステムの安定稼働を支える運用保守プロジェクトです。本ポジションでは、FIチームのリーダーとして、チーム全体の計画管理、作業・進捗・課題管理を担います。また、海外関係会社への展開支援や、引継ぎ期間におけるメンバーのサポートなど、グローバルな視点でのリーダーシップを発揮していただきます。 主な業務内容:

運用保守チームリーダーとしての計画管理、作業・進捗・課題管理
海外関係会社への展開支援を含む、全体計画の策定と作業管理
引継ぎ期間におけるメンバーの進捗・課題管理、および報告
お客様やチーム内の定例・臨時会議の主催、およびファシリテーション
対応メンバーへの技術的・業務的サポート

【MM】

【SD】

【商社SAP（SD/MMマスタ移行ツール）】東京（リモート併用）／設計・改修

: ～1,400,000円 / 月

: 東京都

: 要件定義, 設計

稼働率：: 100%

作業内容：

商社向けSAPプロジェクトのマスタチームにおいて、マスタデータ（特に品目マスタ）移行の効率化とユーザービリティ向上がミッションです。現在の移行ツールは使いづらい点があり、UI改善を含めた、より優れたツールへの改修が求められています。本ポジションでは、既存ツールの部品（BAdI、汎用ツール等）を有効活用し、省エネルギーで効果的なツールの設計・改修、テスト、移行までを中心メンバーとして担当していただきます。 主な業務内容:

マスタ（特に品目）移行ツール（ファイルアップロードツール）の設計・改修
ユーザーインターフェース（UI）の改善を含む、外部設計書の作成
改修したツールのテスト計画、および実施
実際のデータ移行におけるツール利用支援
既存ツールの部品（BAdI、汎用ツール等）の調査・活用検討

【PP】

【S/4HANA新規導入（PP）】富山（リモート併用）／要件定義・IF設計

: ～1,550,000円 / 月

: 富山県

: 要件定義

稼働率：: 100%

作業内容：

SAP S/4HANAの新規導入プロジェクトが進行しており、要件定義フェーズにおいてPP（生産計画/管理）領域を推進していただけるコンサルタントを募集いたします。顧客と直接コミュニケーションを取りながら、最適な業務プロセスとシステム設計（インターフェース含む）を定義する、非常に重要な役割です。本ポジションでは、これまでに培われたPPの専門知識と適用設計のスキルを存分に発揮していただくことを期待しています。 主な業務内容:

PPモジュールにおける要件定義、および顧客との適用設計
PPの標準機能に関する調査、およびカスタマイズ設定
インターフェース（I/F）の設計、および開発連携

【PP】

【S/4HANA新規導入（PP設計）】フルリモート（都内）／基本設計

: ～800,000円 / 月

: フルリモート

: 設計, 開発（ABAP/Fiori）

稼働率：: 100%

作業内容：

大手エネルギー会社向けSAP S/4 HANA新規導入プロジェクトにおいて、基本設計業務をご担当いただきます。本ポジションでは、PP（生産計画/管理）領域の専門家として、新システムの基盤となる基本設計を中心メンバーとして推進していただくことを期待しています。 主な業務内容:

SAP S/4 HANA PPモジュールにおける基本設計書の作成
要件定義に基づいた、システム機能の具体化
アドオン機能の設計、およびFiori画面の設計（ご経験に応じて）
開発チームや他モジュール担当者との連携、調整
関連ドキュメントの作成および更新

【MM】

【SD】

【大手製造業S/4HANA Cloud導入（MM/SD）】埼玉・東京（ハイブリッド）／要件定義リード

: ～1,300,000円 / 月

: 東京都

: 要件定義

稼働率：: 100%

作業内容：

大手製造業の基幹システムとして、S/4HANA Cloud Public Editionを導入するプロジェクトです。本ポジションでは、Fit-to-Standardアプローチを前提とし、クライアント側のロジスティクス領域担当として業務要件の整理からシステム要件定義、設定検討までを主体的にリードしていただきます。特に検討が薄いMM領域を重点的にご担当いただきます。 主な業務内容:

物流や調達に関する業務要件の整理と、システム要件への落とし込み（Fit-to-Standard）
SAPで使用する機能と業務のスコープの明確化
関連するマスターデータ（品目マスター、組織マスター等）の設計、およびインターフェースの仕様検討
クライアント側主担当者のパートナーとして、資料作成や詳細検討を推進
現場部門との調整、および課題の整理・改善案の検討

【FI】

【大手製造業S/4HANA Cloud導入（FI）】埼玉・東京（ハイブリッド）／要件定義リード

: ～1,300,000円 / 月

: 東京都

: 要件定義

稼働率：: 100%

作業内容：

大手製造業の基幹システムとして、S/4HANA Cloud Public Editionを導入するプロジェクトです。本ポジションでは、Fit-to-Standardアプローチを前提とし、クライアント側の会計領域担当として業務要件の整理からシステム要件定義、設定検討までを主体的にリードしていただきます。PL/BSに関する議論が中心となるため、FIの深い知見が求められます。 主な業務内容:

業務フローや業務一覧を基に、SAP標準機能での実現可否を明確化（Fit-to-Standard）
SAPでの運用案、およびSAP外での代替業務案（ワークアラウンド）の検討・提案
SAPベンダーとの技術的な対話をサポートし、クライアントチームを支援
業務部門と協働し、実現可能な新業務フローの構築
既存システムとのインターフェース要件定義の検討支援
ワークショップにおけるディスカッションの支援、および経理・会計部門との調整・課題解決

【SD】

【中堅製造業SAP新規導入（SD設計）】フルリモート／基本設計・オフショア連携

: ～1,000,000円 / 月

: フルリモート

: 設計

稼働率：: 100%

作業内容：

現行のAS400システムからSAP（SD, MM, PP, FI, CO）への新規導入プロジェクトです。本ポジションでは、プロジェクトの重要なフェーズである基本設計において、SDモジュールの設計作業を中心メンバーとして担当していただきます。特に、受注、出荷、ロット管理、在庫引当といったコアな業務領域が対象となります。 主な業務内容

SAP SDモジュール（受注、出荷、ロット管理、在庫引当）における基本設計書の作成
要件定義に基づいた、システム機能の具体化
オフショア（大連）の開発チームへの設計内容の説明、およびQ&A対応
関連ドキュメントの作成および更新

【FI】

【SAP FI運用保守（チームリード）】フルリモート／計画管理・海外展開支援

: ～1,200,000円 / 月

: フルリモート

: 運用・保守

稼働率：: 100%

作業内容：

運用保守チームリーダーとしての計画管理、作業・進捗・課題管理
海外関係会社への展開支援を含む、全体計画の策定と作業管理
引継ぎ期間におけるメンバーの進捗・課題管理、および報告
お客様やチーム内の定例・臨時会議の主催、およびファシリテーション
対応メンバーへの技術的・業務的サポート

【FI】

【自動車部品メーカーSAP導入（FI-AA）】フルリモート／設計・カスタマイズ

: ～1,100,000円 / 月

: フルリモート

: 設計

稼働率：: 100%

作業内容：

自動車部品メーカーの基幹システムとしてSAPを導入するプロジェクトです。本ポジションでは、プロジェクトの重要な局面である要件定義後期から基本設計フェーズにおいて、FI-AA（固定資産）の専門家としてご参画いただきます。固定資産モジュールに関するカスタマイズやアドオン設計を中心メンバーとして担当していただきます。 主な業務内容

FI-AA（固定資産）モジュールに関するカスタマイズの設計、および実装
アドオン機能の基本設計、および設計書の作成
要件定義の後期フェーズにおける、仕様の具体化および顧客との調整
関連ドキュメントの作成および更新

【MM】

【S/4HANA導入支援（MM移行）】東京・上野（基本リモート）／移行・テスト・課題対応

: ～1,300,000円 / 月

: 東京都

: 設計, テスト, その他

稼働率：: 100%

作業内容：

SAP S/4HANAの新規導入プロジェクトにおいて、MM（在庫購買管理）領域のデータ移行を成功させることがミッションです。本ポジションでは、MMの専門家として、データ移行の実行からテスト、発生した課題への対応まで、移行フェーズにおける一連の業務を主体的に推進していただきます。 主な業務内容:

MM領域のマスタデータおよびトランザクションデータの移行支援
移行後のデータ検証、およびテストの実施
移行やテストで発生した課題の調査、分析、および解決策の提示
関連チームとの連携、および進捗報告
関連ドキュメントの作成および更新

新着のSAP案件をもっと見る

この記事のポイント

バッチインプットとは？

バッチインプットとは、SAP上で手作業で入力する動作をプログラムで再現し自動入力させる手法です。
アドオンプログラムの中でバッチインプットの処理をすることが可能で、大量のマスタデータやトランザクションデータを処理する際に便利です。

しかしバッチインプットにもデメリットがあります。

バッチインプットプログラムのデメリット

処理速度が遅い。
SAPのバージョンやGUIのバージョンの違いにより、画面仕様（画面名や画面項目名や画面遷移など）が異なる場合に動かなくなってしまう可能性があります。

対象のマスタデータやトランザクションデータを更新するためのBAPIが準備されていれば、BAPIを用いる方がよいでしょう。

バッチインプットレコーダーの使用方法

バッチインプットレコーダーとは、SAPの画面を実際に動かしたとき、システム的にどのような挙動をしているのかを記録するものです。
この結果を元にバッチインプットプログラムを作成していきます。
（慣れたらバッチインプットレコーダーを使わずともバッチインプット用のプログラムを作成できるようになるかも）

さっそくバッチインプットレコーダーを動かしてみましょう！
ここではT-CODE：MM01（品目マスタ登録）をレコーディングしていきます。

バッチインプットレコーダーを使ってみる

バッチインプットレコードを登録してみましょう。
ここでは品目マスタ登録（T-CODE：MM01）のバッチインプットをレコーディングしていく例をみていきます！

まず、T-CODE：SHDBを起動し、「新規記録」を押下します。

以下の項目に入力します。

レコード
T-CODE：SHDBの一覧画面に表示されるレコード名になります。分かりやすい名称にしましょう。
トランザクションCode
バッチインプットさせたいトランザクションコードを入力します。
バックグラウンドシミュレーションモード
オンライン実行とバックグラウンド実行で挙動が異なるトランザクションコードが存在します。
その場合はバッチインプットで動作させたい実行モードに合わせて設定します。

ここでは例として品目マスタ登録（T-CODE：MM01）を行っています。
以下のように登録する品目の情報を入力していきます。

品目コード/産業コード/品目タイプを入力してENTER
基本データ1/基本データ2 ビューを選択してENTER

次に以下の手順を実行します。

基本データ1：品目テキスト/基本数量単位/品目グループを入力してENTER
基本データ2：標準テキスト/危険物インジケーターPを入力してENTER

最後に登録確認用のポップアップが出力されるので「Yes」を押下

以上で品目マスタ登録（T-CODE：MM01）での操作は終わりになります！

次に表示される画面は、品目マスタ登録（T-CODE：MM01）を操作した際のバッチインプットレコードの内容です。

バッチインプットレコーダーで記録したものは、SAPで操作した全ての動作や自動で入力された内容も入っており、実際にバッチインプットを動かす際には不要となるレコードも含まれています

バッチインプットのレコードの見方

プログラム/Dynproのブロックごとに画面での動作を表しています。

下図のように1つの画面に対して1つのプログラム/Dynproのブロックに対応しており、例えばT-CODE：MM01の最初の画面はプログラム：SAPLMGMM/Dynpro：0060のブロックで確認できます。

また、1つのプログラム/Dynproのブロック毎に1つのOKCODEのレコード（項目名が「BDC_OKCODE」のレコード）が存在しています。
これはENTERや実行ボタンなどを押下した場合の内部的なコードを示しています。

加えて、トランザクションコードから呼び出した画面で入力した項目は、以下のようにバッチインプットレコード上でどの項目名に対してどのような項目値を入力したかが記録されています。

項目名が「BDC_CURSOR」や「BDC_SUBSCR」のレコードはカーソルがどの項目に当てられているかが記録されていますが、これはバッチインプットの処理上では不要である場合がほとんどです。

記録されたバッチインプットレコード

これまでに記録されたバッチインプットレコードの内容を見てみましょう。

プログラム	Dynpro	開始ID	項目名	項目値
SAPLMGMM	0060	X
			BDC_CURSOR	RMMG1-MATNR
			BDC_OKCODE	=ENTR
			RMMG1-MATNR	test_mat_sato01
			RMMG1-MBRSH	M
			RMMG1-MTART	ROH
SAPLMGMM	0070	X
			BDC_CURSOR	MSICHTAUSW-DYTXT(02)
			BDC_OKCODE	=ENTR
			MSICHTAUSW-KZSEL(01)	X
			MSICHTAUSW-KZSEL(02)	X
SAPLMGMM	4004	X
			BDC_OKCODE	/00
			BDC_SUBSCR	SAPLMGMM 2004TABFRA1
			BDC_SUBSCR	SAPLMGD1 1002SUB1
			MAKT-MAKTX	test material
			BDC_SUBSCR	SAPLMGD1 2001SUB2
			BDC_CURSOR	MARA-MATKL
			MARA-MEINS	PC
			MARA-MATKL	ZBRAKES
			MARA-MSTAE	03
			BDC_SUBSCR	SAPLMGD1 2561SUB3
			BDC_SUBSCR	SAPLMGD1 2007SUB4
			BDC_SUBSCR	SAPLMGD1 2005SUB5
			BDC_SUBSCR	SAPLMGD1 2011SUB6
			BDC_SUBSCR	SAPLMGD1 2033SUB7
			BDC_SUBSCR	SAPLMGD1 0001SUB8
			BDC_SUBSCR	SAPLMGD1 0001SUB9
			BDC_SUBSCR	SAPLMGD1 0001SUB10
SAPLMGMM	4004	X
			BDC_OKCODE	/00
			BDC_SUBSCR	SAPLMGMM 2004TABFRA1
			BDC_SUBSCR	SAPLMGD1 1002SUB1
			MAKT-MAKTX	test material
			BDC_SUBSCR	SAPLMGD1 2002SUB2
			MARA-NORMT	aaaaa
			BDC_SUBSCR	SAPLMGD1 2010SUB3
			BDC_CURSOR	MARA-PROFL
			MARA-PROFL	001
			BDC_SUBSCR	SAPLLO_SGT_MM 2016SUB4
			BDC_SUBSCR	SAPLMGD1 2003SUB5
			BDC_SUBSCR	SAPLMGD1 2004SUB6
			BDC_SUBSCR	SAPLMGD1 2499SUB7
			BDC_SUBSCR	SAPLADRT21 2000SUB8
			BDC_SUBSCR	SAPLFGSCMPRD_DYN 3011SUB9
			BDC_SUBSCR	SAPLMGD1 2012SUB10
SAPLSPO1	0300	X
			BDC_OKCODE	=YES

「BDC_CURSOR」や「BDC_SUBSCR」はカーソルの位置を表すもので、実際にコーディングする際は不要なレコードになります。一部の場合を除いて、大抵の場合は不要とみなして良いでしょう。
それらを削除したレコードは以下になります。

プログラム	Dynpro	開始ID	項目名	項目値
SAPLMGMM	0060	X
			BDC_OKCODE	=ENTR
			RMMG1-MATNR	test_mat_sato01
			RMMG1-MBRSH	M
			RMMG1-MTART	ROH
SAPLMGMM	0070	X
			BDC_OKCODE	=ENTR
			MSICHTAUSW-KZSEL(01)	X
			MSICHTAUSW-KZSEL(02)	X
SAPLMGMM	4004	X
			BDC_OKCODE	/00
			MAKT-MAKTX	test material
			MARA-MEINS	PC
			MARA-MATKL	ZBRAKES
			MARA-MSTAE	03
SAPLMGMM	4004	X
			BDC_OKCODE	/00
			MAKT-MAKTX	test material
			MARA-NORMT	aaaaa
			MARA-PROFL	001
SAPLSPO1	0300	X
			BDC_OKCODE	=YES

上記のうち、色が付いているレコードは画面上でデフォルトで入力されている項目値であり、バッチインプットの際も自動入力されるのでコーディングする際には不要になるレコードになります。
それらを削除したレコードは以下になります。

プログラム	Dynpro	開始ID	項目名	項目値
SAPLMGMM	0060	X
			BDC_OKCODE	=ENTR
			RMMG1-MATNR	test_mat_sato01
			RMMG1-MBRSH	M
			RMMG1-MTART	ROH
SAPLMGMM	0070	X
			BDC_OKCODE	=ENTR
			MSICHTAUSW-KZSEL(01)	X
			MSICHTAUSW-KZSEL(02)	X
SAPLMGMM	4004	X
			BDC_OKCODE	/00
			MAKT-MAKTX	test material
			MARA-MEINS	PC
			MARA-MATKL	ZBRAKES
SAPLMGMM	4004	X
			BDC_OKCODE	/00
			MARA-NORMT	aaaaa
			MARA-PROFL	001
SAPLSPO1	0300	X
			BDC_OKCODE	=YES

だいぶスッキリしましたね。
この内容と同じバッチインプットレコードのデータを用いれば、品目マスタを登録できるはずです。

バッチインプットプログラムを作成

実際にABAPを用いてバッチインプットプログラムを作ってみましょう。

バッチインプットセッションを登録してT-CODE：SM35で実行する方法もありますが、今回はプログラムの中から直接トランザクションコードを呼び出してバッチインプットする方法を解説します。

バッチインプットプログラムの作成手順は以下になります。

バッチインプットプログラムの処理の流れ

通称「BDCテーブル」と呼ばれる内部テーブルを作成
標準で準備されている構造「BDCDATA」を用い、先ほど編集したバッチインプットレコードと同様の構造で内部テーブルを作成します。
CALL TRANSACTIONでトランザクションコードを呼び出し
BDCテーブルの内容でトランザクションコードを動かします。
メッセージ内容を読み込み後続処理
バッチインプット結果はメッセージに格納されているので、そのメッセージを読み込み成功した場合/失敗した場合でログを残す等の処理を行います。

実際のプログラムを見た方が早いと思いますので、先ほどの品目マスタ作成の例を用いてサンプルプログラムをお見せします！

サンプルプログラム

以下の前提条件でサンプルプログラムを作成してみました。

同じ品目コードを登録することはできないので、ここでは選択画面で登録する品目コードを入力させるようにしています。
バッチインプット後のメッセージはWRITE分で出力しています。
SAPやGUIのバージョンにより期待値通りに動作しないことがあります。

ABAPを用いたバッチインプットのサンプルコード

*&---------------------------------------------------------------------*
*& Report ZTEST_SATO20
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
REPORT ztest_sato20 NO STANDARD PAGE HEADING.

* 選択項目定義
PARAMETERS:
  p_matnr TYPE mara-matnr. " 品目コード

* 変数定義
DATA:
  it_bdcdata    TYPE TABLE OF bdcdata,   " BDCテーブル
  it_bdcmsgcoll TYPE TABLE OF bdcmsgcoll. " バッチインプット処理メッセージ

* 主処理
START-OF-SELECTION.

* 品目マスタ登録の第一画面
  PERFORM bdc_dynpro      USING 'SAPLMGMM' '0060'.
  PERFORM bdc_field       USING 'BDC_OKCODE'
                                '=ENTR'.
  PERFORM bdc_field       USING 'RMMG1-MATNR'
                                p_matnr.        " 選択画面で入力した品目コード
  PERFORM bdc_field       USING 'RMMG1-MBRSH'
                                'M'.
  PERFORM bdc_field       USING 'RMMG1-MTART'
                                'ROH'.

* 品目マスタ登録のビュー選択画面
  PERFORM bdc_dynpro      USING 'SAPLMGMM' '0070'.
  PERFORM bdc_field       USING 'BDC_OKCODE'
                                '=ENTR'.
  PERFORM bdc_field       USING 'MSICHTAUSW-KZSEL(01)'
                                'X'.
  PERFORM bdc_field       USING 'MSICHTAUSW-KZSEL(02)'
                                'X'.

* 品目マスタ登録の基本データ1画面
  PERFORM bdc_dynpro      USING 'SAPLMGMM' '4004'.
  PERFORM bdc_field       USING 'BDC_OKCODE'
                                '/00'.
  PERFORM bdc_field       USING 'MAKT-MAKTX'
                                'test material'.
  PERFORM bdc_field       USING 'MARA-MEINS'
                                'PC'.
  PERFORM bdc_field       USING 'MARA-MATKL'
                                'ZBRAKES'.

* 品目マスタ登録の基本データ2画面
  PERFORM bdc_dynpro      USING 'SAPLMGMM' '4004'.
  PERFORM bdc_field       USING 'BDC_OKCODE'
                                '/00'.
  PERFORM bdc_field       USING 'MARA-NORMT'
                                'aaaaa'.
  PERFORM bdc_field       USING 'MARA-PROFL'
                                '001'.

* 品目マスタの登録確認画面
  PERFORM bdc_dynpro      USING 'SAPLSPO1' '0300'.
  PERFORM bdc_field       USING 'BDC_OKCODE'
                                '=YES'.

* バッチインプット処理
  CALL TRANSACTION 'MM01'      " MM01を実行
             USING it_bdcdata  " バッチインプットデータ
              MODE 'N'         " 処理モード
            UPDATE 'A'         " 更新モード
          MESSAGES INTO it_bdcmsgcoll.

* メッセージ出力処理
  LOOP AT it_bdcmsgcoll INTO DATA(wa_bdcmsgcoll) .
*   メッセージを格納
    MESSAGE ID wa_bdcmsgcoll-msgid
          TYPE wa_bdcmsgcoll-msgtyp
        NUMBER wa_bdcmsgcoll-msgnr
          WITH wa_bdcmsgcoll-msgv1
               wa_bdcmsgcoll-msgv2
               wa_bdcmsgcoll-msgv3
               wa_bdcmsgcoll-msgv4
          INTO DATA(l_text).

*   メッセージを出力
    WRITE /001 l_text.

  ENDLOOP.

*----------------------------------------------------------------------*
*        Start new screen                                              *
*----------------------------------------------------------------------*
FORM bdc_dynpro USING program TYPE c
                      dynpro  TYPE c.
* 変数定義
  DATA:
    wa_bdcdata TYPE bdcdata. " BDC構造

  CLEAR wa_bdcdata.
  wa_bdcdata-program  = program.
  wa_bdcdata-dynpro   = dynpro.
  wa_bdcdata-dynbegin = 'X'.
  APPEND wa_bdcdata TO it_bdcdata.
ENDFORM.
*----------------------------------------------------------------------*
*        Insert field                                                  *
*----------------------------------------------------------------------*
FORM bdc_field USING fnam TYPE c
                     fval TYPE c.
* 変数定義
  DATA:
    wa_bdcdata TYPE bdcdata. " BDC構造

  CLEAR wa_bdcdata.
  wa_bdcdata-fnam = fnam.
  wa_bdcdata-fval = fval.
  APPEND wa_bdcdata TO it_bdcdata.
ENDFORM.

サンプルプログラムの解説

内部テーブル「it_bdcdata」がBDCテーブルです。
このBDCテーブルに対して、関数「bdc_dynpro（画面名の設定）」「bdc_field（項目入力値やOKコードの設定）」を用いて、バッチインプット用のレコードを格納させていきます。

その後、CALL TRANSACTIONでT-CODE：MM01を呼び出します。

CALL TRANSACTIONのパラメータ

CALL TRANSACTIONでは複数のパラメータを設定することができます。
以下に解説しますが、いろいろ試してみてどういう動作をするか実際動作確認してみると良いでしょう。

CALL TRANSACTIONのパラメータ名	パラメータの解説
USING （使用するBDCテーブル）	BDCテーブルを設定します。
MODE （処理モード）	バッチインプット時の画面を表示するかどうか設定をすることができます。【設定内容】 A：すべての画面を表示 E：エラー画面のみ表示 N：画面の表示はしない ※AやEはテスト時に使う場合が多く、たいていの場合はNを設定します。
UPDATE （更新モード）	データの更新モードを設定することができます。 ※指定しない場合はAになります。【設定内容】 A：非同期更新　更新の終了を待たず次の処理を行います。　処理は早いですがロックエラー等の原因にもなります。 S：同期更新　更新の終了まで待機し、終了したら次の処理を行います。　非同期更新より処理は遅くなります。 L：ローカル更新呼出元プログラムと同じダイアログプロセスで実行します。※筆者は使ったことありません。
MESSAGES INTO （メッセージテーブル）	バッチインプットの処理中に表示されるメッセージを格納する内部テーブルを設定します。例えば、エラーのメッセージタイプのメッセージのみ取り出してログに出力するような使用をします。構造は「BDCMSGCOLL」を参照します。

博士

ちょっとだけABAP7.4以降の新構文を取り入れているので、以下も参考に見比べてみると良いのじゃ！

サンプルプログラムの実行

最後にサンプルプログラムを実際に動かしてみて、期待値通りに動作するか確認してみましょう！

パターン①：既存の品目コードを入力して実行

既に登録されている品目コードを選択画面へ入力して、品目マスタを登録してみましょう。
このパターンは想定されていなかったので品目マスタへの登録は失敗するはずです。

実行した結果は以下になります。
期待値通りに、品目マスタは更新されませんでした。

実際の開発では、既存の品目コードが入力された場合も考慮してBDCテーブルを作成する必要があります！

バッチインプットで入力されるであろうデータについて、あらゆるパターンを考慮してBDCテーブルを作成するようにすべし！

パターン②：新規の品目コードを入力して実行

次に登録されていない品目コードを選択画面に入力して実行してみましょう。
この場合は品目マスタの登録に成功するはずです。

実行した結果は以下になります。

メッセージの内容的にも品目マスタが登録された旨が表示され、T-CODE：MM03でも品目マスタが登録されていることが確認できました！

さいごに

バッチインプットを用いたアドオンプログラムは便利な機能ですが、すべての入力パターンを網羅してBDCテーブルを作成することや、実行結果をログに残し失敗したデータをどうやってリカバリするかまで検討して設計することが重要になります。

博士

バッチインプットに関する解説は以上じゃ！

博士

SAPラボでは、SAPの知識を活かして副業をしたい方を募集してるのじゃ！

SAPラボのライターの特徴

・ライティング初心者OK！
・報酬高単価！
・業務委託契約なので副業として最適！

SAP記事執筆者としての活動実績として利用可能なので、転職時や案件探しの際に企業へのアピール材料にもなります。

募集要項

・SAP導入や運用保守プロジェクトへの参画経験1年以上

ご応募/お問合せ先

info@sap-labo.com

少しでもご興味ある方、ぜひお気軽にご連絡下さい！

よかったらシェアしてね！

URLをコピーしました！

この記事を書いた人

佐藤皓紀

株式会社スプラッシュエンジニアリング（https://splash-eng.com/）の代表取締役。

新卒でSAPエンジニアとして働き始め、SAPエンジニア・コンサルタント歴は10年以上。
2015年にシステム開発会社である株式会社Luxyを創業し2021年にバイアウト。その後、受託開発会社の株式会社アガルートITパートナーズ代表取締役も兼任。
2024年にこれまでの会社の代表を退任し株式会社スプラッシュエンジニアリングを創業。

一緒に「SAPラボ」を盛り上げてくれる副業ライター(SAP経験者)を募集してますので、お問い合わせよりお願いします！