【SAP ABAP】バッチインプットの概要とプログラム(CALL TRANSACTION)の作成方法を徹底解説！

*&---------------------------------------------------------------------*
*& Report ZTEST_SATO20
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
REPORT ztest_sato20 NO STANDARD PAGE HEADING.

* 選択項目定義
PARAMETERS:
  p_matnr TYPE mara-matnr. " 品目コード

* 変数定義
DATA:
  it_bdcdata    TYPE TABLE OF bdcdata,   " BDCテーブル
  it_bdcmsgcoll TYPE TABLE OF bdcmsgcoll. " バッチインプット処理メッセージ

* 主処理
START-OF-SELECTION.

* 品目マスタ登録の第一画面
  PERFORM bdc_dynpro      USING 'SAPLMGMM' '0060'.
  PERFORM bdc_field       USING 'BDC_OKCODE'
                                '=ENTR'.
  PERFORM bdc_field       USING 'RMMG1-MATNR'
                                p_matnr.        " 選択画面で入力した品目コード
  PERFORM bdc_field       USING 'RMMG1-MBRSH'
                                'M'.
  PERFORM bdc_field       USING 'RMMG1-MTART'
                                'ROH'.

* 品目マスタ登録のビュー選択画面
  PERFORM bdc_dynpro      USING 'SAPLMGMM' '0070'.
  PERFORM bdc_field       USING 'BDC_OKCODE'
                                '=ENTR'.
  PERFORM bdc_field       USING 'MSICHTAUSW-KZSEL(01)'
                                'X'.
  PERFORM bdc_field       USING 'MSICHTAUSW-KZSEL(02)'
                                'X'.

* 品目マスタ登録の基本データ1画面
  PERFORM bdc_dynpro      USING 'SAPLMGMM' '4004'.
  PERFORM bdc_field       USING 'BDC_OKCODE'
                                '/00'.
  PERFORM bdc_field       USING 'MAKT-MAKTX'
                                'test material'.
  PERFORM bdc_field       USING 'MARA-MEINS'
                                'PC'.
  PERFORM bdc_field       USING 'MARA-MATKL'
                                'ZBRAKES'.

* 品目マスタ登録の基本データ2画面
  PERFORM bdc_dynpro      USING 'SAPLMGMM' '4004'.
  PERFORM bdc_field       USING 'BDC_OKCODE'
                                '/00'.
  PERFORM bdc_field       USING 'MARA-NORMT'
                                'aaaaa'.
  PERFORM bdc_field       USING 'MARA-PROFL'
                                '001'.

* 品目マスタの登録確認画面
  PERFORM bdc_dynpro      USING 'SAPLSPO1' '0300'.
  PERFORM bdc_field       USING 'BDC_OKCODE'
                                '=YES'.

* バッチインプット処理
  CALL TRANSACTION 'MM01'      " MM01を実行
             USING it_bdcdata  " バッチインプットデータ
              MODE 'N'         " 処理モード
            UPDATE 'A'         " 更新モード
          MESSAGES INTO it_bdcmsgcoll.

* メッセージ出力処理
  LOOP AT it_bdcmsgcoll INTO DATA(wa_bdcmsgcoll) .
*   メッセージを格納
    MESSAGE ID wa_bdcmsgcoll-msgid
          TYPE wa_bdcmsgcoll-msgtyp
        NUMBER wa_bdcmsgcoll-msgnr
          WITH wa_bdcmsgcoll-msgv1
               wa_bdcmsgcoll-msgv2
               wa_bdcmsgcoll-msgv3
               wa_bdcmsgcoll-msgv4
          INTO DATA(l_text).

*   メッセージを出力
    WRITE /001 l_text.

  ENDLOOP.

*----------------------------------------------------------------------*
*        Start new screen                                              *
*----------------------------------------------------------------------*
FORM bdc_dynpro USING program TYPE c
                      dynpro  TYPE c.
* 変数定義
  DATA:
    wa_bdcdata TYPE bdcdata. " BDC構造

  CLEAR wa_bdcdata.
  wa_bdcdata-program  = program.
  wa_bdcdata-dynpro   = dynpro.
  wa_bdcdata-dynbegin = 'X'.
  APPEND wa_bdcdata TO it_bdcdata.
ENDFORM.
*----------------------------------------------------------------------*
*        Insert field                                                  *
*----------------------------------------------------------------------*
FORM bdc_field USING fnam TYPE c
                     fval TYPE c.
* 変数定義
  DATA:
    wa_bdcdata TYPE bdcdata. " BDC構造

  CLEAR wa_bdcdata.
  wa_bdcdata-fnam = fnam.
  wa_bdcdata-fval = fval.
  APPEND wa_bdcdata TO it_bdcdata.
ENDFORM.